Vault batch.
authortheTower <mwclaws@gmail.com>
Thu, 18 Sep 2014 02:48:20 +0000 (22:48 -0400)
committertheTower <mwclaws@gmail.com>
Thu, 18 Sep 2014 02:48:20 +0000 (22:48 -0400)
A small slice of my old ideas and drafts, fixed-up.
Mini-vaults for Lair, Crypt, Elf, and the Hells;
small decoration for Spider and Swamp;
large decoration for Spider and Zot;
and large vaults for Depths, Dis, Tartarus, and Zot.
Some are quite unorthodox.

crawl-ref/source/dat/des/branches/crypt.des
crawl-ref/source/dat/des/branches/dis.des
crawl-ref/source/dat/des/branches/elf.des
crawl-ref/source/dat/des/branches/lair.des
crawl-ref/source/dat/des/branches/spider.des
crawl-ref/source/dat/des/branches/swamp.des
crawl-ref/source/dat/des/branches/tar.des
crawl-ref/source/dat/des/branches/zot.des
crawl-ref/source/dat/des/variable/float.des
crawl-ref/source/dat/des/variable/mini_monsters.des

index a595c88..df9abcf 100644 (file)
@@ -1091,6 +1091,56 @@ MAP
 ......................................
 ENDMAP
 
+NAME:    hangedman_crypt_dual_shrines
+TAGS:    no_monster_gen no_item_gen patrolling
+DEPTH:   Crypt
+# Choose two of the following:
+# Yred nearly-all-melee set, Kiku necro-casters set, ghosts set, tomb set.
+MONS:    minotaur zombie / ettin zombie / skeletal warrior w:20
+MONS:    death knight, bone dragon w:14 / profane servitor
+MONS:    necromancer / vampire w:6 / soul eater w:2
+MONS:    vampire mage / deep elf death mage, lich / reaper w:2
+MONS:    shadow wraith / phantasmal warrior / ghost crab w:4
+KMONS:   8 = eidolon / flayed ghost
+KMONS:   9 = revenant / unborn
+KMONS:   A = guardian mummy / skeleton w:8 / flying skull band w:6
+KMONS:   B = ancient champion
+KMONS:   C = mummy priest
+KMONS:   0 = zombie
+ITEM:    any weapon good_item ego:draining, any weapon ego:pain
+ITEM:    scroll of torment ident:type, randbook disc:necromancy numspells:3
+ITEM:    lantern of shadows, staff of death ident:type
+ITEM:    amulet of warding randart good_item
+KITEM:   $ = $ no_pickup
+KFEAT:   D = altar_yredelemnul
+KFEAT:   E = altar_kikubaaqudgha
+SHUFFLE: 123D / 456E / 789D / ABCE, defghijk
+SUBST:   * = * |:2, F = c..
+MAP
+        ccccccccccccc
+        c0.v$$1cccccc
+        cc0v...ccc*cccc
+        c..v.c.cc2dDccc
+        cc.v.c.....d*cc
+        c..+.....F.3ccc
+        cc.v....F..cccc
+  ccccccc..+.c.....cccc
+ .c.c.c....v..V......1c
+@..........v.c.c..cc.$c
+cvvvvvvvvvvv1........$c
+c$........4vvvvvvvvvvvc
+c$.cc..c.c.v..........@
+c4......V..+....c.c.c.
+cccc.....c.v..ccccccc
+cccc..F....+.cc
+ccc6.F.....v..c
+cc*e.....c.v.cc
+cccEe5cc.c.v..c
+cccc*ccc...v0cc
+  cccccc4$$v.0c
+  ccccccccccccc
+ENDMAP
+
 ##############################################################################
 # Crypt ends
 ##############################################################################
index ebbc25a..09477fe 100644 (file)
@@ -592,6 +592,61 @@ MAP
              .....
 ENDMAP
 
+# The rent rates are ridiculous.
+NAME:    hangedman_iron_city_apartments
+TAGS:    transparent no_pool_fixup layout_type_city layout_type_passages
+DEPTH:   Dis, !Dis:$
+ORIENT:  float
+MONS:    skeletal warrior / vampire w:6 / wight w:2          / \
+         zombie / skeleton / hell hound / iron devil w:14    / \
+         red devil / blue devil / sun demon w:6              / \
+         ice devil w:6 / hellwing / soul eater w:6
+MONS:    reaper / hellion / tormentor / executioner w:2      / \
+         bone dragon / lich / ancient champion               / \
+         balrug w:2 / blizzard demon w:2 / shadow demon w:2  / \
+         iron dragon w:2 / quicksilver dragon w:2
+KFEAT:   Z = known zot trap
+# Standard floor spawn equipment drops, not real loot.
+KITEM:   d = battleaxe no_pickup / great mace no_pickup      / \
+             great sword no_pickup / glaive no_pickup        / \
+             scythe good_item no_pickup w:5
+: dgn.delayed_decay(_G, 'e', 'human skeleton')
+NSUBST:  > = 1 = ((<d / 1 = ))>e / 2 = >:1 .:49 / * = ...de
+# Always place at least one door per room, possibly wider or multiplied.
+# Variation provided across either half of the vault and per-room.
+NSUBST:  A = 1:+ / *:-, B = 1:+ / *:-, C = 1:+ / *:-, D = 1:+ / *:-
+NSUBST:  E = 1:+ / *:-, F = 1:+ / *:-, G = 1:+ / *:~, H = 1:+ / *:~
+NSUBST:  I = 1:+ / *:~, J = 1:+ / *:~, K = 1:+ / *:~, L = 1:+ / *:~
+NSUBST:  ! = 1 : +:1 v:9 / * : +:1 v:49
+SUBST:   - : -_, ~ : -_, - = vv+, _ = v++
+SUBST:   V = vvGwlZ...
+NSUBST:  Z = 2:Z / *:.
+# No more than two bosses per room, and always have some of each extreme.
+SHUFFLE: MNOPQRSTUWXY
+NSUBST:  M = 2 = 1:3 2:1 .:1 / * = 1:4 .:1, N = 2 = 1:3 2:1 .:1 / * = 1:4 .:1
+NSUBST:  O = 2 = 1:3 2:1 .:1 / * = 1:4 .:1, P = 2 = 1:3 2:1 .:1 / * = 1:4 .:1
+NSUBST:  Q = 2 = 1:3 2:1 .:1 / * = 1:4 .:1, R = 2 = 1:3 2:1 .:1 / * = 1:4 .:1
+NSUBST:  S = 2 = 1:3 2:1 .:1 / * = 1:4 .:1, T = 2 = 1:3 2:1 .:1 / * = 1:4 .:1
+NSUBST:  U = 1:. / 1:1 / * = 1:4 .:1, W = 2:. / 1:1 / 1 = 1:4 .:1
+NSUBST:  X = 1:2 / 1 = 1:3 2:1 .:1 / * = 1:4 .:1, Y = 2:2 / * = 1:4 .:1
+KMASK:   wl = no_monster_gen
+# : dis_statues(_G)
+MAP
+ ...............................................
+ v..V...vvvBBBvvv...V...vvvDDDvvv...V...vvvFFFvv
+.v......vN.....Nv.......vP.....Pv.......vR....Rv.
+.vvAAAvvv...V...vvvCCCvvv...V...vvvEEEvvv...V..v.
+.vM....MvN..>..NvO.....OvP..>..PvQ.....QvR..>.Rv.
+.v..V...vvvvvvvvv...V...vvvvvvvvv...V...vvvvvvvv.
+.vM.>..M!T..>..T!O..>..O!W..>..W!Q..>..Q!Y..>.Yv.
+.vvvvvvvv...V...vvvvvvvvv...V...vvvvvvvvv...V..v.
+.vS.>..SvT.....TvU..>..UvW.....WvX..>..XvY....Yv.
+.v..V...vvvHHHvvv...V...vvvJJJvvv...V...vvvLLLvv.
+.vS....Sv.......vU.....Uv.......vX.....Xv......v.
+ vvGGGvvv...V...vvvIIIvvv...V...vvvKKKvvv...V..v
+ ...............................................
+ENDMAP
+
 default-depth:
 ##############################################################################
 # Dispater's castle - subvaulted, with three main versions
index b8a5896..758343c 100644 (file)
@@ -1161,6 +1161,45 @@ x...xxxxxx
 x..xx
 ENDMAP
 
+NAME:    hangedman_elven_crosses_minicolossus
+TAGS:    no_monster_gen transparent misc_elf_vault
+DEPTH:   Elf
+MONS:    deep elf conjurer, deep elf knight / deep elf priest w:6
+MONS:    deep elf fighter / deep elf mage
+MONS:    dancing weapon ; short sword ego:flaming | short sword ego:freezing | \
+                          short sword ego:venom | short sword ego:electrocution
+# Some basic excessive pillar randomization work,
+# with spokes per-cross and centers in mirrored / half pairs.
+SUBST:   A : xxcb..., B : xxcb..., C : xxcb..., D : xxcb...
+SHUFFLE: EFGHIJKL / EFIJGHKL, EFGH / FEHG
+SHUFFLE: IJKL / JILK, MNOP / MONP, +Q
+SUBST:   EG : xxcb, IK : xxcb, FHJL = .
+SUBST:   MN : x., OP : x., Q = x
+MAP
+    .@.xxxxxx
+    @x.+...xx
+    ..3x.A.xxxxx
+   xx+xx...xxxxxxxx
+   xx...EFE..*xxxxx.@.
+   xx.A.FMF.A2x...+.x@
+  xxx...EFE..*x.B.x3..
+  xxxxxx.4.xxxx...xx+x
+  xx*2*x.A.Q...IJI...x
+xxxx.D.x..1+.B4JNJ.B.x
+xxxx...xQ+cc1..IJI...x
+x...KLK..1cc+Qx...xxxx
+x.D.LPL4D.+1..x.B.xxxx
+x...KLK...Q.C.x*2*xx
+x+xx...xxxx.4.xxxxxx
+..3x.D.x*..GHG...xxx
+@x.+...x2C.HOH.C.xx
+.@.xxxxx*..GHG...xx
+   xxxxxxxx...xx+xx
+      xxxxx.C.x3..
+         xx...+.x@
+         xxxxxx.@.
+ENDMAP
+
 ##############################################################################
 ##############################################################################
 #
index 3552cf1..b7a1e62 100644 (file)
@@ -2402,6 +2402,30 @@ MAP
  ...    .....E
 ENDMAP
 
+NAME:    hangedman_lair_generics_rect
+TAGS:    no_monster_gen
+DEPTH:   Lair
+MONS:    plant / fungus w:6
+NSUBST:  ' = 2:c / 2:. / * = c+....
+SHUFFLE: yY / yY / Yy
+SUBST:   y = ., Yz = xxxx1., Z = xx`
+CLEAR:   `
+MAP
+.............xZZ
+.c'c'c'c'c'cxxxZZ
+.'...........zxxZ
+.c..0.....0..zxxx
+.'...Wxxxx...xx%x
+.c...xxxxx...x9.x
+.'...xxxxW..xx.9x
+.c..0......Y.x..x
+.x........x.y.xxx
+xxzzzzzzxxxx..%xx
+Zxxxxxxxx9..x%0xx
+ZZxxxxxx%.9.xxxzx
+ ZZZZZxxxxxxxxxxx
+ENDMAP
+
 ###############################################################################
 # Lair endings
 ###############################################################################
index ffc2448..c68f94a 100644 (file)
@@ -1287,6 +1287,98 @@ xxWWWxxWxxx
   xxxxxxx
 ENDMAP
 
+NAME:   hangedman_spider_mandibles
+TAGS:   extra transparent decor
+DEPTH:  Spider
+# 59 inside blocks, 59 outside blocks.
+NSUBST: x = 6:. / 9 = xx. / *:x
+NSUBST: z = 4:. / 4:' / 9 = xxx''. / *:x
+CLEAR:  '
+MAP
+      zzzzzzz
+     zz.....zz
+    zz...x...zz
+    z...xxx...z
+   zzx...x...xzz
+  @z.x.......x.z@
+ @z...xx...xx...z@
+ z.....xx.xx.....z
+ zx..xxx...xxx..xz
+zz.x.x.......x.x.zz
+z..xxx.......xxx..z
+z..xx....x....xx..z
+ z.x....xxx....x.z
+z..x....xxx....x..z
+z..xx....x....xx..z
+zz..xx.......xx..zz
+ zz.............zz
+  zzzz..@.@..zzzz
+ENDMAP
+
+# Bah, bu bah, bu ba-ba-ba ba-ba-ba baa, bu ba-ba-ba buh.
+NAME:    hangedman_spider_tarantella_strand
+TAGS:    extra transparent decor
+DEPTH:   Spider
+ORIENT:  north
+MONS:    tarantella
+# The size of the vault means this upped weight is actually akin
+# to the usual vault weight. The vault is highly random and ends
+# up being very unobtrusive for most Spider layouts, anyway.
+WEIGHT:  25
+# Very selectively, partially ruin the edge of the beats.
+NSUBST:  A = 1:. / 2 = X / *:x, B = 1:. / 2 = X / *:x
+NSUBST:  C = 1:. / 2 = X / *:x, D = 4:. / 4 = X / *:x
+NSUBST:  E = 1:X / *:x, F = 1:X / *:x, G = 1:X / *:x
+NSUBST:  H = 1:X / *:x, I = 1:X / *:x, J = 1:X / *:x
+NSUBST:  K = 1:X / *:x, L = 1:X / *:x, M = 1:X / *:x
+NSUBST:  N = 1:X / *:x, O = 1:X / *:x, P = 1:X / *:x
+# Even random trimming can have weighed styles to it.
+SUBST:   z : ^<>, ^ = xx', < = xx''', > = x'
+SUBST:   y : XYZ, X = xx., Y = xx..., Z = x.
+SUBST:   X : %*|, % = xxx.., * = x., | = xx...
+SUBST:   " : "`;, " = ..', ` = ...', ; = .'
+CLEAR:   '
+# The string here pushes the vault from the level border.
+MAP
+                             '
+                             '
+                             '
+                             '
+                             '
+                             '
+                             '
+                             '
+                             '
+                             '
+                             '
+                             '
+                             '
+                             '
+                             '
+                             '
+                             '
+                             '
+                             '
+                             '
+                             '
+xzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzx
+xyyyyyyyyyyyyyyyyxzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzz
+.................yzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzz
+.................xyyyyyyyyyyyyyyyyyyxzzzzzzzzzzzzzzzzzzzzzzzzz
+.AAAA....BBBB.............1.........yzzzzzzzzzzzzzzzzzzzzzzzzz
+"AxxA.EE.BxxB.FF....................xyyyyyyyyyyyyyyyyyxzzzzzzz
+"AxxA.EE.BxxB.FF..GG.......JJ.........................yzzzzzzz
+.AAAA....BBBB.....GG.HH....JJ.KK......................xyyyyyyx
+.....................HH.II....KK.LL..CCCC....NN...............
+ .""..""..""..""........II.......LL..CxxC.MM.NN.OO.....DDDDDD.
+                 ....................CxxC.MM....OO.PP..DxxxxD.
+                 @"".""."".""."".""..CCCC..........PP..DxxxxD"
+                                    ...................DxxxxD"
+                                    @."".."".""."".""..DxxxxD.
+                                                      .DDDDDD.
+                                                      ...""..
+ENDMAP
+
 ##############################################################################
 # Rune vaults
 ##############################################################################
index acdcd3e..e25d738 100644 (file)
@@ -640,6 +640,32 @@ MAP
            @
 ENDMAP
 
+NAME:    hangedman_swamp_pad
+TAGS:    transparent extra no_pool_fixup decor
+KMONS:   P = plant
+KFEAT:   P = shallow_water
+SHUFFLE: AB / AB / BA, CD / CD / DC, EF / EF / FE
+SUBST:   A = t, B = ., C : Pt~.., D = ., E = t, F = P
+KMASK:   ~ = no_monster_gen
+SUBST:   ~ = w
+MAP
+   .www.www.
+  .w...w...w.
+ .w.B.t.t.B.w.
+.w.A.ttttt.A.w.
+w.B.t..C..t.B.w
+w..t...D...t..w
+w.tt..EFE..tt.w
+.w.tCDFtFDCt.w.
+w.tt..EFE..tt.w
+w..t...D.wwt..w
+w.B.t..C.wPw..w
+.w.A.tttttwPw.w
+ .w.B.t.t..wPw.
+  .w...w....w.
+   .www.wwww.
+ENDMAP
+
 #####
 # The ruins of a town... all that is left are a few buildings
 # and skeletons. These vaults are just to give swamp some variety...
index 5ea3f0c..2662ac1 100644 (file)
@@ -620,6 +620,43 @@ cccccccccccccccccccx
 xxxxxxxxxxxxxxxxxxxx
 ENDMAP
 
+# A bit of a tribute to Jory's old silence vault, except
+# hopefully this time with some choice in using the silence;
+# the aura extends to the edge of the walls with the main doors.
+NAME:    hangedman_tartarus_silent_blood_keep
+TAGS:    no_monster_gen transparent patrolling
+DEPTH:   Tar, !Tar:$
+ORIENT:  float
+WEIGHT:  5
+MONS:    zombie / skeleton / spectral thing w:4
+MONS:    jiangshi / phantasmal warrior w:4 / shadow wraith w:4, vampire mage
+MONS:    vampire knight ; demon whip | demon trident | demon blade . \
+                          plate armour | chain mail
+MONS:    soul eater, tormentor w:3 / shadow demon w:1, silent spectre
+KMONS:   9 = reaper / lorocyproca w:6
+KMONS:   J = Jory w:9 / shadow fiend w:1, shadow fiend
+NSUBST:  J = 1:J / *:9, 8 = 1:6 / * = 5:19 6:1
+SUBST:   A : x.., B : x.., ] = ]>
+MAP
+          xx  xx  xx  xx  xx  xx
+         xxxxxxxxxxxxxxxxxxxxxxxxx
+       xxxxxxxxxxxxxxxxxxxxxxxxxxx
+      ..xx..xx..........xx.........
+    ....A......4c.3..4...B.....ccc...
+  .............ccc+ccc......82ccccc..
+...ccc1.......ccc.2.ccc..cccccc2c2cc.
+..ccccc18ccccccc)56..ccccc....+..7cc.
+.cc2c2cccc....+J.3<4.J+....cccc2c2cc.
+.cc7..+....ccccc..65]ccccccc81ccccc..
+.cc2c2cccccc..ccc.2.ccc.......1ccc...
+..ccccc82......ccc+ccc.............
+...ccc.....B...3..4.c3......A....
+  .........xx..........xx..xx..
+   xxxxxxxxxxxxxxxxxxxxxxxxxxxx
+   xxxxxxxxxxxxxxxxxxxxxxxxxx
+     xx  xx  xx  xx  xx  xx
+ENDMAP
+
 ##############################################################################
 # Ereshkigal (Tartarus)
 ##############################################################################
index 09a6347..eeeff4a 100644 (file)
@@ -2290,6 +2290,107 @@ Be..x...Ck..x.Et......
    Ci...qD
 ENDMAP
 
+NAME:    hangedman_moon_palace_of_the_dragon_emperor
+TAGS:    extra decor no_pool_fixup
+DEPTH:   Zot, !Zot:$
+ORIENT:  float
+MONS:    plant col:random name:demonic name_adjective tile:mons_demonic_plant
+ITEM:    stone q:1 no_pickup, large rock q:1 no_pickup, mundane cloak no_pickup
+ITEM:    scroll of random uselessness q:1 ident:type no_pickup
+ITEM:    needle ego:poisoned q:1 no_pickup, mundane dagger no_pickup
+ITEM:    potion of poison q:1 ident:type no_pickup
+KFEAT:   A = stone_arch
+: dgn.delayed_decay(_G, 'j', 'draconian skeleton')
+SHUFFLE: {}, tT'"
+SUBST:   t = T, " = '
+SUBST:   l : l+mv, G : Gc1, T : TUAdefg, ' : hijk'
+KPROP:   ' = bloody
+KMASK:   defghij = no_item_gen
+TILE:    c : dngn_stone_wall_red / wall_icy_stone / wall_cobalt_stone
+COLOUR:  G = cyan
+TILE:    G = dngn_statue_iron
+: set_feature_name("granite_statue", "iron statue")
+MAP
+                            bbbbbbbbbbbbb
+                  bbbbbbbbbbbbb...l...bbb
+          bbbbbbbbbbb..l..bbbb.........bb
+    bbbbbbbb..l..bbb.......bb...........b
+bbbbbb.l.bb.......b.........b...........b
+btl'b.t.'.b..t.'..b...t.'...b....t.'....b
+b.{....C......C...0....C..........}.....b
+bTG"b.T.".b..T."..b...T."...b....T."....b
+bbbbbb.G.bb.......b.........b...........b
+    bbbbbbbb..G..bbb.......bb...........b
+          bbbbbbbbbbb..G..bbbb.........bb
+                  bbbbbbbbbbbbb...G...bbb
+                            bbbbbbbbbbbbb
+ENDMAP
+
+# Inspired by a distant submission from nicolae-,
+# a revelation: nothing in Zot makes any sense!
+NAME:    hangedman_orp_of_zott
+TAGS:    no_monster_gen
+DEPTH:   Zot, !Zot:$
+ORIENT:  northwest
+WEIGHT:  5
+# Cheap plastic imitations, mostly. Well, maybe not cheap...
+MONS:    ugly thing w:15 / raiju / guardian serpent / harpy zombie / \
+         base draconian perm_ench:shapeshifter / boggart / \
+         orb spider w:5 / great orb of eyes w:5 / rakshasa w:5
+MONS:    very ugly thing w:20 / deep elf annihilator w:15 / \
+         deep elf death mage w:15 / balrug w:15 / octopode crusher / \
+         quicksilver dragon / unborn / crystal guardian
+MONS:    curse skull w:15 / apocalypse crab / lorocyproca / acid blob
+MONS:    butterfly
+ITEM:    stone q:1 no_pickup, large rock q:1 no_pickup
+ITEM:    sling bullet q:1 no_pickup, crystal ball of energy no_pickup
+# Altars obliquely refer to those temple maps.
+KFEAT:   D = altar_lugonu / altar_jiyva / altar_beogh w:5 / C w:20
+KFEAT:   ~ = known zot trap
+SHUFFLE: Xy / Xy / Xy / Aa
+NSUBST:  A = 1:. / 19 = X:9 .:1 / *:X
+SUBST:   X : X Y Z:4, X = bbbbvnc, Y = bvvvvnc, Z = bbvnncc
+SUBST:   az = bbvc, y = x, B : x.
+NSUBST:  2 = 4 = 2223 / *:2, . = 3:0 / 3 = 9. / 1:4 / *:., 1 = 1:1.. / *:1
+# 1/15 chance for two downward staircases, 9/15 for (only) one.
+SHUFFLE: ])defG, fgGCD~
+MAP
+xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
+xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
+xx1.............+''''''''''''''''''''''''''''''
+xx1.............+'''''''''''''''''''''''''''''''
+xXX......XXXXXXXXXXXXXXX''''''XXXXXXXXXXXXXX'''''
+xzXX......XyyyyyyyyyyyX''''''XXyyyyyyyyyyyyXX''''
+xyyXX.....XXyxxxxxxxyXX'''''XXyyxxxxxxxxxxyyXX'''
+xxyyXX....%XyxxBBBxxyX1....XXyyxxxxxxxxxxxxyyXX''
+xxxyyX....1zzxxxBxxxzz.....XyyxxxxxxxxxxxxxxyyX''
+xxxxyX....%z2.x.1.x.2z1....XyxxxxxxxxxxxBxxxxyX'
+xxxxyX....Xzx...]...xzX....XyxxxxxxxxxBBxBxxxyX'
+xxxyyX....Xz%.x...x.%zX....XyyxxxxxxBBxxxxBxxyX''
+xxyyXX...Xzzzzzz+zzzzzzX...XXyyxxxd........2zzX''
+xxyXX...zzz1.........1zzz...XXyxxxxx......%zzX'''
+xxyX...zzX1...........1Xzz...Xyyyyyyyy1..1zzX''''
+xxXX+++z.................z+++XXXXXXXzzzz+zzX''''
+xx1...................................+112z1'''
+xxXX.........................XXXXXXXzzzz+zzX''''
+xxyXXXX...................XXXXyyyyyyy1...1zzX''''
+xxxyyyXXX...............XXXyyyyxxx%.......%zzX'''
+xxxxxyyyXX.............XXyyyxxxe...........2zzX'
+xxxxxxxyyX...zzz1zzz...XyyxxxxxxxxBBBxxxxxByyXX'
+xxxxxxxxyX..Xz1z+z1zX..XyxxxxxxxxxxxxBBBxBxyXX'''
+xxxxxxxxyX.2zzX%%%Xzz2.XyxxxxxxxxxxxxxxxBxyyX'''
+xxxxxxxxyzzzz1.%)%.1zzzzyxxxxxxxxxxxxxxxxxyX1''
+xxxxxxxxyX'1zzX%%%Xzz1'XyxxxxxxxxxxxxxxxxxyyX'''
+xxxxxxxxyX''Xz2zzz2zX''XyxxxxxxxxxxxxxxxxxxyXX'''
+xxxxxxxyyX'''zzz1zzz'''XyyxxxxxxxxxxxxxxxxxyyXX'
+xxxxxyyyXX'''''''''''''XXyyyxxxxxxxxxxxxxxxyyXX'
+xxyyyyXXX'''''''''''''''XXXyyyyxxxxxxxxxyyyyXX'''
+xyyXXXX'''''''''''''''''''XXXXyyyyyyyyyyyXXXX'''
+xXXX'''''''''''''''''''''''''XXXXXXXXXXXXX'''''
+xx''''''''''''''''''''''''''''''''''''''''''''
+   ''''''   ''''@''''   '''''''''   '''''''''
+ENDMAP
+
 ##############################################################################
 ##############################################################################
 #
index c3a1edb..b1dead9 100644 (file)
@@ -6393,3 +6393,65 @@ cc%..c.9..c....c..9.c..*cc
       cc$.c....c.$cc
        cccc.@@.cccc
 ENDMAP
+
+# Originally a rather long D encompass vault, cropped, shrunk,
+# and re-arranged to preserve the idea with less of the problems.
+# (The monsters do wander a little too easily now, but the vault
+# hardly sticks out compared to the rest of Depths.)
+NAME: hangedman_grunt_twisty_little_passages
+TAGS: no_monster_gen
+DEPTH: Depths, !Depths:$
+ORIENT: float
+SHUFFLE: defghijk
+SUBST: def = c, ghi = v, jk = b
+KMONS: 8 = 8 band
+KMONS: 9 = 9 band
+KMONS: 0 = 0 band
+KITEM: J = acquire any
+NSUBST: | = 1:J / 2:* / *:|
+SUBST: % = %., O = %
+MAP
+eeeeeeeeeffffffffffffffffffffffffffffffffkk
+eeeeeeeeecfffffffffffffffffffffffffffffffkk
+ee0......ecff%%.....................%Oxxxkk
+ee........ecf%%.....................%%xxxkk
+.ee...ee...ecf...0fffffffffffffff0...fcxxkk
+@.ee...ee...ecf...fffffffffffffff...fci%Okk
+...ee...ee...ecf...fff|%....8fff...fci.%%kk
+e...ee...ee..0ecf...ff*%....9ff...fci....kk
+ce...e...ee...eecf...ff...ffff...fci.....kk
+dce.....ee...eeeecf...ff...ff...fci...0..kk
+ddce...ee...ee0..ecf...ff...0..fci...ii..kk
+ddgce0ee...ee.....ecf...ff....fci...iii..kk
+ddggcee0..ee...e...ecf...ff..fci...iiii..kk
+dd%%gce...ee0..ee...ecf..0fffci...iiiii..kk
+dd%%.gce...ee...ee...ecf...cci...ii98ii..kk
+dd....gce...ee...ee...ee...0ci..0ii..ii..kk
+dd.....gce...ee...ee.........ii...i..ii..kk
+dd..0...gce...ee...ee........8ii.....ii..kk
+dd..gg...gce...ee...ee9...ci...ii....ii..kk
+dd..ggg...gce...e..0ee...jjci...ii.%%ii..kk
+dd..gggg...gce.....ee%..jj0jci...ii*|ii..kk
+dd..ggggg...gce...ee%O%jj...jci...iiiii..kk
+dd..gg*|gg...gce0ee..%jj.....jci...iiii..kk
+dd..gg%%.gg...gcee...jj0..j...jci...iii..kk
+dd..gg....gg...gc...9jj...jj...jci...ii..kk
+dd..gg.....gg8........jj...jj...jci...0..kk
+dd..gg..g...gg.........jj...jj...jci.....kk
+dd..gg..gg0..gc0...jj...jj...jj...jci....kk
+dd..gg89gg...gcc...ccj...jj...jj...jci.%%kk
+dd..ggggg...gchhh0..hcj...jj..0jj...jci%%kk
+dd..gggg...gch..hh...hcj...j...jj..0jjciikk
+dd..ggg...gch....hh...hcj.....jj...jj0jcikk
+dd..gg...gch...0..hh...hcj..0jj...jj...jckk
+dd..0...gch...hh...hh...hcjjjj...jj.....jck
+dd.....gch...hhhh...hh...hcjj...jj...j...jc
+dd....gch...hh9....%|hh...hcj0..jj...jj...j
+dd%%.gch...hhh8....%*hhh...hcj...jj...jj...
+ddO%gch...hhhhhhhhhhhhhhh...hcj...jj...jj.@
+ddxxch...0hhhhhhhhhhhhhhh0...hcj...jj...jj.
+ddxxx%%.....................%%hcj........jj
+ddxxxO%.....................%%hhcj......0jj
+ddhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhcjjjjjjjjj
+ddhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhjjjjjjjjj
+ENDMAP
index d872340..08150a7 100644 (file)
@@ -5609,6 +5609,87 @@ x.....wcc..ccw......
      ....xtx...
 ENDMAP
 
+# Of course, since there are special_rooms already,
+# a real dedication here has to step it up a little.
+NAME:    hangedman_mysterious_dungeon_monster_house
+TAGS:    no_monster_gen no_item_gen no_trap_gen no_pool_fixup allow_dup luniq
+DEPTH:   Geh:2-, !Geh:$, Coc:2-, !Coc:$, Tar:2-, !Tar:$, Dis:2-, !Dis:$
+WEIGHT:  5
+# Specific allotment of monsters, terrain, and items for this small box.
+# Monsters are in three tiers: generic undead, specific fodder, bosses.
+# Terrain includes known zot traps, and per-hell clouds, liquid, statues.
+# Items include generic hellspawn weapon drops and free skeletons.
+NSUBST:  . = 2:0 / 1:9 / 2:8 / 4 = 9:3 0:1 / 1 = 8:6 / 7:1 / *:.
+NSUBST:  . = 1:* / 1:d / 6 = *:2 d:3 / *:.
+NSUBST:  . = 1:^ / 1:^~ / 1:F~ / 4 = F~~ / 1:( / 1:> / *:.
+KMONS:   0 = zombie / skeleton / necromancer w:6
+KITEM:   * = battleaxe no_pickup / great mace no_pickup / \
+             great sword no_pickup / glaive no_pickup / \
+             scythe good_item no_pickup w:5 / demon whip no_pickup w:5 / \
+             demon blade no_pickup w:5 / demon trident no_pickup w:5
+: dgn.delayed_decay(_G, 'd', 'human skeleton')
+KFEAT:   ^ = known zot trap
+: if you.branch() == "Geh" then
+KMONS:   9 = sun demon / smoke demon / hell knight / \
+             red devil w:5 / efreet w:5
+KMONS:   8 = hellion / balrug / salamander firebrand
+KMONS:   7 = brimstone fiend
+MARKER:  F = lua:fog_machine {cloud_type = "flame", \
+             pow_min = 8, pow_max = 10, delay = 100, \
+             size_min = 1, size_max = 1, start_clouds = 1, excl_rad = 0 }
+SUBST:   ~ = l
+FTILE:   F = floor_volcanic
+COLOUR:  F = lightred
+: elseif you.branch() == "Coc" then
+KMONS:   9 = ice devil / blue devil w:5 / ice dragon / simulacrum w:5 / \
+             skeletal warrior ; hunting sling ego:freezing ident:type . \
+             mundane sling bullet . mace ego:freezing ident:type
+KMONS:   8 = blizzard demon / lich / reaper ; scythe ego:freezing ident:type
+KMONS:   7 = ice fiend
+MARKER:  F = lua:fog_machine {cloud_type = "freezing vapour", \
+             pow_min = 8, pow_max = 10, delay = 100, \
+             size_min = 1, size_max = 1, start_clouds = 1, excl_rad = 0 }
+SUBST:   ~ = w
+FTILE:   F = floor_nerves_blue
+COLOUR:  F = lightblue
+: elseif you.branch() == "Tar" then
+KMONS:   9 = soul eater / shadow demon / vampire mage / flayed ghost
+KMONS:   8 = tormentor / revenant / mummy priest
+KMONS:   7 = shadow fiend
+MARKER:  F = lua:fog_machine {cloud_type = "foul pestilence", \
+             pow_min = 8, pow_max = 10, delay = 100, \
+             size_min = 1, size_max = 1, start_clouds = 1, excl_rad = 0 }
+SUBST:   ~ = G
+FTILE:   F = floor_crystal_squares
+COLOUR:  F = lightmagenta
+: elseif you.branch() == "Dis" then
+KMONS:   9 = ynoxinul / iron devil w:5 / vampire knight w:5 / \
+             phantasmal warrior / skeletal warrior ; mundane arbalest . \
+             mundane bolt . mace good_item
+KMONS:   8 = war gargoyle / iron dragon /  \
+             dancing weapon ; great sword good_item | great mace good_item | \
+                              glaive good_item | battleaxe good_item
+MONS:    7 = hell sentinel
+SUBST:   xc = v, F~ = G
+COLOUR:  G = cyan
+TILE:    G = dngn_statue_iron
+: set_feature_name("granite_statue", "iron statue")
+: end
+KPROP:   lw = no_rtele_into
+MAP
+xxxxxxxxxxxx
+xccccccccccx
+xc........cx
+xc........cx
+xc........cx
+xc........cx
+xc........cx
+xc........cx
+xc........cx
+xccccccccccx
+xxxxxxxxxxxx
+ENDMAP
+
 ################################################################
 #
 # <<8>> Minivaults with monsters guarding a thematic item.