# Give cards commands for gccg.
#
# Copyright (C) 2004, 2005 Michael Slone <mps@s-z.org>.
#
# Some modifications (C) 2005 Neil Moore <neil@s-z.org>.
#
# Distributed under the terms of the GNU GPL, version 2.  See COPYING
# for details.

if(msg.box != NULL) {
	Msg("Loading {gold}Give.command");
}

# give(p,c) - Give the card named c to p.
def give
{
	SendMeta("GiveCard", (ARG[0], RecognizeCard(ARG[1])));
}

def ChatCommandGivecard
{
	if(length(ARG) < 2) {
		Msg("{red}Command {gold}givecard{red} requires two arguments.");
	} else {
		give(ARG[0], join(tail(ARG), " "));
	}
}

def ChatCommandGivecards
{
	push(c);
	push(i);
	if(length(ARG) < 2) {
		Msg("{red}Command {gold}givecards{red} requires two arguments.");
	} else {
		i = 0;
		for(c)(split(join(tail(ARG), " "), "+")) {
			give(ARG[0], c);
			i = i+1;
# Pause every few cards, and turn off screen updates between pauses.
			if(i % 2 == 0) {
				refresh(1);
				sleep(1);
				refresh(0);
			}
		}
	}
	refresh(1);

	i = pop();
	c = pop();
}

HELP{"chat"}{"givecard"}=("player,card","give a card",NULL,
"Give the card named {yellow}<card>{white} to {yellow}<player>{white}.");

HELP{"chat"}{"givecards"}=("player,[card1] {cyan}+{yellow} [card2] {cyan}+{yellow} ...",
"give cards",NULL,
"Give cards to {yellow}<player>{white}.");